TCP UDF, Event driven!

SUBMITTED BY: Guest

DATE: May 28, 2013, 5:35 p.m.

FORMAT: Text only

SIZE: 24.9 kB

Raw Download

HITS: 903

Report
  1. #cs ----------------------------------------------------------------------------
  3. AutoIt Version: 3.3.0.0
  4. Author: Kip
  6. Script Function:
  7. TCP UDF v3
  9. #ce ----------------------------------------------------------------------------
  11. ; Script Start - Add your code below here
  13. #cs
  15. Functions:
  17. _TCP_Server_Create($iPort, $sIP="0.0.0.0")
  18. _TCP_Server_Broadcast($sData)
  19. _TCP_Server_ClientList()
  20. _TCP_Server_ClientIP($hSocket)
  21. _TCP_Server_DisconnectClient($hSocket)
  22. _TCP_Server_Stop()
  25. _TCP_Client_Create($sIP , $iPort)
  26. _TCP_Client_Stop($hSocket)
  29. _TCP_Send($hSocket, $sText)
  30. _TCP_RegisterEvent($hSocket, $iEvent, $sFunction)
  33. Register event values:
  35. $TCP_SEND ; Function ($hSocket, $iError)
  36. $TCP_RECEIVE ; Function ($hSocket, $sReceived, $iError)
  37. $TCP_CONNECT ; Function ($hSocket, $iError) => Client only
  38. $TCP_DISCONNECT ; Function ($hSocket, $iError)
  39. $TCP_NEWCLIENT ; Function ($hSocket, $iError) => Server only
  42. #ce
  45. Global Const $FD_READ = 1
  46. Global Const $FD_WRITE = 2
  47. Global Const $FD_OOB = 4
  48. Global Const $FD_ACCEPT = 8
  49. Global Const $FD_CONNECT = 16
  50. Global Const $FD_CLOSE = 32
  51. Global $hWs2_32 = -1
  53. Global Const $TCP_SEND = 1
  54. Global Const $TCP_RECEIVE = 2
  55. Global Const $TCP_CONNECT = 4
  56. Global Const $TCP_DISCONNECT = 8
  57. Global Const $TCP_NEWCLIENT = 16
  60. TCPStartup()
  61. Global Const $__TCP_WINDOW = GUICreate("Async Sockets UDF")
  62. Global $__TCP_SOCKETS[1][7]
  69. ; #FUNCTION# ;===============================================================================
  70. ;
  71. ; Name...........: _TCP_Server_Create
  72. ; Description ...: Initializes the server.
  73. ; Syntax.........: _TCP_Server_Create($iPort, $sIP="0.0.0.0")
  74. ; Parameters ....: $iPort - The port number the server should listen to.
  75. ; $sIP - IP address. (Default = "0.0.0.0")
  76. ; Return values .: The socket handle.
  77. ; Author ........: Kip
  78. ; Modified.......:
  79. ; Remarks .......: Only 1 server can be created per script.
  80. ; Related .......:
  81. ; Link ..........;
  82. ; Example .......;
  83. ;
  84. ; ;==========================================================================================
  86. Func _TCP_Server_Create($iPort, $sIP="0.0.0.0")
  88. Local $hListenSocket = ___ASocket()
  91. ___ASockSelect( $hListenSocket, $__TCP_WINDOW, 0x0400, $FD_ACCEPT)
  92. GUIRegisterMsg( 0x0400, "___TCP_OnAccept" )
  95. ___ASockListen( $hListenSocket, $sIP, $iPort )
  97. $__TCP_SOCKETS[0][0] = $hListenSocket
  98. $__TCP_SOCKETS[0][1] = 0x0400
  100. Return $hListenSocket
  102. EndFunc
  108. Func ___TCP_OnAccept($hWnd, $iMsgID, $WParam, $LParam)
  110. Local $hSocket = $WParam
  111. Local $iError = ___HiWord( $LParam )
  112. Local $iEvent = ___LoWord( $LParam )
  114. Local $hClient, $uBound
  116. Abs($hWnd) ; Stupid AU3Check...
  118. If $iMsgID = $__TCP_SOCKETS[0][1] Then
  120. If $iEvent = $FD_ACCEPT Then
  122. If Not $iError Then
  124. ReDim $__TCP_SOCKETS[UBound($__TCP_SOCKETS)+1][7]
  125. $uBound = UBound($__TCP_SOCKETS)
  127. $hClient = TCPAccept($hSocket)
  129. ___ASockSelect($hClient, $__TCP_WINDOW, 0x0400 + $uBound - 1, BitOR($FD_READ, $FD_WRITE, $FD_CLOSE))
  130. GUIRegisterMsg(0x0400 + $uBound - 1, "___TCP_Server_OnSocketEvent" )
  132. $__TCP_SOCKETS[UBound($__TCP_SOCKETS)-1][0] = $hClient
  133. $__TCP_SOCKETS[UBound($__TCP_SOCKETS)-1][1] = 0x0400 + $uBound - 1
  135. Call($__TCP_SOCKETS[0][6], $hClient, $iError)
  137. Else
  139. Call($__TCP_SOCKETS[0][6], 0, $iError)
  141. EndIf
  143. ElseIf $iEvent = $FD_CONNECT Then
  145. Call($__TCP_SOCKETS[0][4], $hSocket, $iError)
  147. EndIf
  149. EndIf
  152. EndFunc
  159. ; #FUNCTION# ;===============================================================================
  160. ;
  161. ; Name...........: _TCP_Client_Stop
  162. ; Description ...: Stops the client.
  163. ; Syntax.........: _TCP_Client_Stop($hSocket)
  164. ; Parameters ....: $hSocket - Client socket.
  165. ; Return values .: Success - True
  166. ; Failure - False
  167. ; Author ........: Kip
  168. ; Modified.......:
  169. ; Remarks .......: The client socket is the return value of _TCP_Client_Create().
  170. ; Related .......:
  171. ; Link ..........;
  172. ; Example .......;
  173. ;
  174. ; ;==========================================================================================
  176. Func _TCP_Client_Stop($hSocket)
  178. Local $iElement, $i
  180. $iElement = 0
  182. For $i = 1 to UBound($__TCP_SOCKETS)-1
  184. If $__TCP_SOCKETS[$i][0] = $hSocket Then
  185. $iElement = $i
  186. ExitLoop
  187. EndIf
  189. Next
  191. If $iElement Then
  193. ___ASockShutdown($__TCP_SOCKETS[$iElement][0])
  194. TCPCloseSocket($__TCP_SOCKETS[$iElement][0])
  196. ___ArrayDelete($__TCP_SOCKETS, $iElement)
  198. Return True
  200. EndIf
  202. Return False
  204. EndFunc
  212. ; #FUNCTION# ;===============================================================================
  213. ;
  214. ; Name...........: _TCP_Server_Stop
  215. ; Description ...: Stops the server, and closes all client connections.
  216. ; Syntax.........: _TCP_Server_Stop()
  217. ; Parameters ....:
  218. ; Return values .: True
  219. ; Author ........: Kip
  220. ; Modified.......:
  221. ; Remarks .......:
  222. ; Related .......:
  223. ; Link ..........;
  224. ; Example .......;
  225. ;
  226. ; ;==========================================================================================
  228. Func _TCP_Server_Stop()
  230. Local $i
  232. ___ASockShutdown($__TCP_SOCKETS[0][0])
  233. TCPCloseSocket($__TCP_SOCKETS[0][0])
  235. $__TCP_SOCKETS[0][0] = ""
  236. $__TCP_SOCKETS[0][1] = ""
  237. $__TCP_SOCKETS[0][2] = ""
  238. $__TCP_SOCKETS[0][3] = ""
  239. $__TCP_SOCKETS[0][4] = ""
  240. $__TCP_SOCKETS[0][5] = ""
  241. $__TCP_SOCKETS[0][6] = ""
  243. For $i = UBound($__TCP_SOCKETS)-1 to 1 Step -1
  244. ___ArrayDelete($__TCP_SOCKETS, $i)
  245. Next
  247. Return True
  249. EndFunc
  256. Func ___TCP_Server_OnSocketEvent( $hWnd, $iMsgID, $WParam, $LParam )
  258. Local $hSocket = $WParam
  259. Local $iError = ___HiWord( $LParam )
  260. Local $iEvent = ___LoWord( $LParam )
  262. Local $sDataBuff, $iElement, $i
  264. Abs($hWnd)
  266. $hSocket = 0
  267. $iElement = 0
  269. For $i = 1 to UBound($__TCP_SOCKETS)-1
  271. If $__TCP_SOCKETS[$i][1] = $iMsgID Then
  272. $hSocket = $__TCP_SOCKETS[$i][0]
  273. $iElement = $i
  274. ExitLoop
  275. EndIf
  277. Next
  279. If $hSocket Then
  281. Switch $iEvent
  282. Case $FD_READ
  284. $sDataBuff = TCPRecv($hSocket, 1024)
  286. Call($__TCP_SOCKETS[0][2], $hSocket, $sDataBuff, $iError)
  288. Case $FD_WRITE
  290. Call($__TCP_SOCKETS[0][3], $hSocket, $iError)
  292. Case $FD_CLOSE
  294. ___ASockShutdown($hSocket)
  295. TCPCloseSocket($hSocket)
  297. Call($__TCP_SOCKETS[0][5], $hSocket, $iError)
  299. ___ArrayDelete($__TCP_SOCKETS, $iElement)
  301. EndSwitch
  303. EndIf
  306. EndFunc
  313. ; #FUNCTION# ;===============================================================================
  314. ;
  315. ; Name...........: _TCP_Server_DisconnectClient
  316. ; Description ...: Disconnects a client of the server.
  317. ; Syntax.........: _TCP_Server_DisconnectClient($hSocket)
  318. ; Parameters ....: $hSocket - Client socket.
  319. ; Return values .: Success - True
  320. ; Failure - False
  321. ; Author ........: Kip
  322. ; Modified.......:
  323. ; Remarks .......: The client socket is the $hSocket parameter of a _TCP_RegisterEvent callback function.
  324. ; Related .......:
  325. ; Link ..........;
  326. ; Example .......;
  327. ;
  328. ; ;==========================================================================================
  330. Func _TCP_Server_DisconnectClient($hSocket)
  332. Local $iElement, $i
  334. $iElement = 0
  336. For $i = 1 to UBound($__TCP_SOCKETS)-1
  338. If $__TCP_SOCKETS[$i][0] = $hSocket Then
  339. $iElement = $i
  340. ExitLoop
  341. EndIf
  343. Next
  345. If $iElement Then
  347. ___ASockShutdown($hSocket)
  348. TCPCloseSocket($hSocket)
  350. ___ArrayDelete($__TCP_SOCKETS, $iElement)
  352. Return True
  354. EndIf
  356. Return False
  358. EndFunc
  365. ; #FUNCTION# ;===============================================================================
  366. ;
  367. ; Name...........: _TCP_Server_ClientList
  368. ; Description ...: Returns the sockets of all connected clients.
  369. ; Syntax.........: _TCP_Server_ClientList()
  370. ; Parameters ....:
  371. ; Return values .: An 1 dimensional array of all connected clients.
  372. ; Author ........: Kip
  373. ; Modified.......:
  374. ; Remarks .......:
  375. ; Related .......:
  376. ; Link ..........;
  377. ; Example .......;
  378. ;
  379. ; ;==========================================================================================
  381. Func _TCP_Server_ClientList()
  383. Local $aReturn[1], $i
  385. For $i = 1 to UBound($__TCP_SOCKETS)-1
  386. If $__TCP_SOCKETS[$i][0] Then
  387. ReDim $aReturn[UBound($aReturn)+1]
  388. $aReturn[UBound($aReturn)-1] = $__TCP_SOCKETS[$i][0]
  389. EndIf
  390. Next
  392. $aReturn[0] = UBound($aReturn)-1
  394. Return $aReturn
  396. EndFunc
  400. ; #FUNCTION# ;===============================================================================
  401. ;
  402. ; Name...........: _TCP_Server_Broadcast
  403. ; Description ...: Sends data to all connected clients.
  404. ; Syntax.........: _TCP_Server_Broadcast($sData)
  405. ; Parameters ....: $sData - The data to send.
  406. ; Return values .: True
  407. ; Author ........: Kip
  408. ; Modified.......:
  409. ; Remarks .......:
  410. ; Related .......:
  411. ; Link ..........;
  412. ; Example .......;
  413. ;
  414. ; ;==========================================================================================
  416. Func _TCP_Server_Broadcast($sData)
  418. Local $i
  420. For $i = 1 to UBound($__TCP_SOCKETS)-1
  422. If $__TCP_SOCKETS[$i][0] Then TCPSend($__TCP_SOCKETS[$i][0], $sData)
  424. Next
  426. Return True
  428. EndFunc
  434. ; #FUNCTION# ;===============================================================================
  435. ;
  436. ; Name...........: _TCP_Client_Create
  437. ; Description ...: Creates a new client.
  438. ; Syntax.........: _TCP_Client_Create($sIP , $iPort)
  439. ; Parameters ....: $sIP - The IP address to connect to.
  440. ; $iPort - Port on which the created socket will be connected.
  441. ; Return values .: Client socket handle.
  442. ; Author ........: Kip
  443. ; Modified.......:
  444. ; Remarks .......:
  445. ; Related .......:
  446. ; Link ..........;
  447. ; Example .......;
  448. ;
  449. ; ;==========================================================================================
  451. Func _TCP_Client_Create($sIP , $iPort)
  453. ReDim $__TCP_SOCKETS[UBound($__TCP_SOCKETS)+1][7]
  455. local $hSocket = ___ASocket()
  457. $__TCP_SOCKETS[UBound($__TCP_SOCKETS)-1][0] = $hSocket
  458. $__TCP_SOCKETS[UBound($__TCP_SOCKETS)-1][1] = 0x0400 + (UBound($__TCP_SOCKETS)-1)
  460. ___ASockSelect( $hSocket, $__TCP_WINDOW, 0x0400 + (UBound($__TCP_SOCKETS)-1), BitOR( $FD_READ, $FD_WRITE, $FD_CONNECT, $FD_CLOSE ) )
  461. GUIRegisterMsg( 0x0400 + (UBound($__TCP_SOCKETS)-1), "___TCP_Client_OnSocketEvent" )
  462. ___ASockConnect( $hSocket, $sIP, $iPort )
  464. Return $hSocket
  466. EndFunc
  472. ; #FUNCTION# ;===============================================================================
  473. ;
  474. ; Name...........: _TCP_RegisterEvent
  475. ; Description ...: Registers an event.
  476. ; Syntax.........: _TCP_RegisterEvent($hSocket, $iEvent, $sFunction)
  477. ; Parameters ....: $hSocket - Socket of the server or a client.
  478. ; $iEvent - Event number. It can be any these values:
  479. ; * $TCP_SEND
  480. ; * $TCP_RECEIVE
  481. ; * $TCP_CONNECT => Client only
  482. ; * $TCP_DISCONNECT
  483. ; * $TCP_NEWCLIENT => Server only
  484. ; Return values .: Success - True
  485. ; Failure - False
  486. ; Author ........: Kip
  487. ; Modified.......:
  488. ; Remarks .......:
  489. ; Related .......:
  490. ; Link ..........;
  491. ; Example .......;
  492. ;
  493. ; ;==========================================================================================
  495. Func _TCP_RegisterEvent($hSocket, $iEvent, $sFunction)
  497. Local $iSelected = 0
  498. Local $i
  500. If $__TCP_SOCKETS[0][0] Then
  502. $iSelected = 0
  504. Else
  506. For $i = 0 to UBound($__TCP_SOCKETS)-1
  507. If $__TCP_SOCKETS[$i][0] = $hSocket Then
  508. $iSelected = $i
  509. ExitLoop
  510. EndIf
  511. Next
  513. If Not $iSelected Then Return 0
  515. EndIf
  517. Switch $iEvent
  518. Case $TCP_SEND
  519. $__TCP_SOCKETS[$iSelected][3] = $sFunction
  520. Case $TCP_RECEIVE
  521. $__TCP_SOCKETS[$iSelected][2] = $sFunction
  522. Case $TCP_CONNECT
  523. $__TCP_SOCKETS[$iSelected][4] = $sFunction
  524. Case $TCP_DISCONNECT
  525. $__TCP_SOCKETS[$iSelected][5] = $sFunction
  526. Case $TCP_NEWCLIENT
  527. $__TCP_SOCKETS[$iSelected][6] = $sFunction
  528. Case Else
  529. Return False
  530. EndSwitch
  532. Return True
  535. EndFunc
  540. ; #FUNCTION# ;===============================================================================
  541. ;
  542. ; Name...........: _TCP_Server_ClientIP
  543. ; Description ...: Converts a client socket handle to IP address.
  544. ; Syntax.........: _TCP_Server_ClientIP($hSocket)
  545. ; Parameters ....: $hSocket - Client socket handle.
  546. ; Return values .: A string with the IP address.
  547. ; Author ........: Unknown
  548. ; Modified.......: Kip
  549. ; Remarks .......:
  550. ; Related .......:
  551. ; Link ..........;
  552. ; Example .......;
  553. ;
  554. ; ;==========================================================================================
  556. Func _TCP_Server_ClientIP($hSocket)
  558. Local $pSocketAddress, $aReturn
  560. $pSocketAddress = DllStructCreate("short;ushort;uint;char[8]")
  561. $aReturn = DllCall("Ws2_32.dll", "int", "getpeername", "int", $hSocket, "ptr", DllStructGetPtr($pSocketAddress), "int*", DllStructGetSize($pSocketAddress))
  562. If @error Or $aReturn[0] <> 0 Then Return 0
  564. $aReturn = DllCall("Ws2_32.dll", "str", "inet_ntoa", "int", DllStructGetData($pSocketAddress, 3))
  565. If @error Then Return 0
  567. $pSocketAddress = 0
  569. Return $aReturn[0]
  571. EndFunc
  577. ; #FUNCTION# ;===============================================================================
  578. ;
  579. ; Name...........: _TCP_Send
  580. ; Description ...: Sends data to a server or client.
  581. ; Syntax.........: _TCP_Send($hSocket, $sText)
  582. ; Parameters ....: $hSocket - Client or server socket handle.
  583. ; $sText - Data to send.
  584. ; Return values .:
  585. ; Author ........: Kip
  586. ; Modified.......:
  587. ; Remarks .......:
  588. ; Related .......:
  589. ; Link ..........;
  590. ; Example .......;
  591. ;
  592. ; ;==========================================================================================
  594. Func _TCP_Send($hSocket, $sText)
  596. Return TCPSend($hSocket, $sText)
  598. EndFunc
  602. Func ___TCP_Client_OnSocketEvent( $hWnd, $iMsgID, $WParam, $LParam )
  604. Local $iError = ___HiWord( $LParam )
  605. Local $iEvent = ___LoWord( $LParam )
  607. Local $hSocket, $iElement, $i, $sDataBuff
  609. Abs($hWnd)
  610. Abs($WParam)
  612. $hSocket = 0
  613. $iElement = 0
  615. For $i = 1 to UBound($__TCP_SOCKETS)-1
  617. If $__TCP_SOCKETS[$i][1] = $iMsgID Then
  618. $hSocket = $__TCP_SOCKETS[$i][0]
  619. $iElement = $i
  620. ExitLoop
  621. EndIf
  623. Next
  625. If $hSocket Then
  627. Switch $iEvent
  628. Case $FD_READ; Data has arrived!
  630. $sDataBuff = TCPRecv( $hSocket, 1024)
  632. Call($__TCP_SOCKETS[$i][2], $hSocket, $sDataBuff, $iError)
  634. $sDataBuff = ""
  636. Case $FD_WRITE
  638. Call($__TCP_SOCKETS[$i][3], $hSocket, $iError)
  640. Case $FD_CONNECT
  642. Call($__TCP_SOCKETS[$i][4], $hSocket, $iError)
  644. Case $FD_CLOSE
  646. ___ASockShutdown( $hSocket )
  647. TCPCloseSocket( $hSocket )
  649. Call($__TCP_SOCKETS[$i][5], $hSocket, $iError)
  651. ___ArrayDelete($__TCP_SOCKETS, $iElement)
  653. EndSwitch
  655. EndIf
  657. EndFunc
  661. ;==================================================================================================================
  662. ;
  663. ; Zatorg's Asynchronous Sockets UDF Starts from here.
  664. ;
  665. ;==================================================================================================================
  668. Func ___ASocket($iAddressFamily = 2, $iType = 1, $iProtocol = 6)
  669. If $hWs2_32 = -1 Then $hWs2_32 = DllOpen( "Ws2_32.dll" )
  670. Local $hSocket = DllCall($hWs2_32, "uint", "socket", "int", $iAddressFamily, "int", $iType, "int", $iProtocol)
  671. If @error Then
  672. SetError(1, @error)
  673. Return -1
  674. EndIf
  675. If $hSocket[ 0 ] = -1 Then
  676. SetError(2, ___WSAGetLastError())
  677. Return -1
  678. EndIf
  679. Return $hSocket[ 0 ]
  680. EndFunc ;==>_ASocket
  682. Func ___ASockShutdown($hSocket)
  683. If $hWs2_32 = -1 Then $hWs2_32 = DllOpen( "Ws2_32.dll" )
  684. Local $iRet = DllCall($hWs2_32, "int", "shutdown", "uint", $hSocket, "int", 2)
  685. If @error Then
  686. SetError(1, @error)
  687. Return False
  688. EndIf
  689. If $iRet[ 0 ] <> 0 Then
  690. SetError(2, ___WSAGetLastError())
  691. Return False
  692. EndIf
  693. Return True
  694. EndFunc ;==>_ASockShutdown
  696. Func ___ASockClose($hSocket)
  697. If $hWs2_32 = -1 Then $hWs2_32 = DllOpen( "Ws2_32.dll" )
  698. Local $iRet = DllCall($hWs2_32, "int", "closesocket", "uint", $hSocket)
  699. If @error Then
  700. SetError(1, @error)
  701. Return False
  702. EndIf
  703. If $iRet[ 0 ] <> 0 Then
  704. SetError(2, ___WSAGetLastError())
  705. Return False
  706. EndIf
  707. Return True
  708. EndFunc ;==>_ASockClose
  710. Func ___ASockSelect($hSocket, $hWnd, $uiMsg, $iEvent)
  711. If $hWs2_32 = -1 Then $hWs2_32 = DllOpen( "Ws2_32.dll" )
  712. Local $iRet = DllCall( _
  713. $hWs2_32, _
  714. "int", "WSAAsyncSelect", _
  715. "uint", $hSocket, _
  716. "hwnd", $hWnd, _
  717. "uint", $uiMsg, _
  718. "int", $iEvent _
  719. )
  720. If @error Then
  721. SetError(1, @error)
  722. Return False
  723. EndIf
  724. If $iRet[ 0 ] <> 0 Then
  725. SetError(2, ___WSAGetLastError())
  726. Return False
  727. EndIf
  728. Return True
  729. EndFunc ;==>_ASockSelect
  731. ; Note: you can see that $iMaxPending is set to 5 by default.
  732. ; IT DOES NOT MEAN THAT DEFAULT = 5 PENDING CONNECTIONS
  733. ; 5 == SOMAXCONN, so don't worry be happy
  734. Func ___ASockListen($hSocket, $sIP, $uiPort, $iMaxPending = 5); 5 == SOMAXCONN => No need to change it.
  735. Local $iRet
  736. Local $stAddress
  738. If $hWs2_32 = -1 Then $hWs2_32 = DllOpen( "Ws2_32.dll" )
  740. $stAddress = ___SockAddr($sIP, $uiPort)
  741. If @error Then
  742. SetError(@error, @extended)
  743. Return False
  744. EndIf
  746. $iRet = DllCall($hWs2_32, "int", "bind", "uint", $hSocket, "ptr", DllStructGetPtr($stAddress), "int", DllStructGetSize($stAddress))
  747. If @error Then
  748. SetError(3, @error)
  749. Return False
  750. EndIf
  751. If $iRet[ 0 ] <> 0 Then
  752. $stAddress = 0; Deallocate
  753. SetError(4, ___WSAGetLastError())
  754. Return False
  755. EndIf
  757. $iRet = DllCall($hWs2_32, "int", "listen", "uint", $hSocket, "int", $iMaxPending)
  758. If @error Then
  759. SetError(5, @error)
  760. Return False
  761. EndIf
  762. If $iRet[ 0 ] <> 0 Then
  763. $stAddress = 0; Deallocate
  764. SetError(6, ___WSAGetLastError())
  765. Return False
  766. EndIf
  768. Return True
  769. EndFunc ;==>_ASockListen
  771. Func ___ASockConnect($hSocket, $sIP, $uiPort)
  772. Local $iRet
  773. Local $stAddress
  775. If $hWs2_32 = -1 Then $hWs2_32 = DllOpen( "Ws2_32.dll" )
  777. $stAddress = ___SockAddr($sIP, $uiPort)
  778. If @error Then
  779. SetError(@error, @extended)
  780. Return False
  781. EndIf
  783. $iRet = DllCall($hWs2_32, "int", "connect", "uint", $hSocket, "ptr", DllStructGetPtr($stAddress), "int", DllStructGetSize($stAddress))
  784. If @error Then
  785. SetError(3, @error)
  786. Return False
  787. EndIf
  789. $iRet = ___WSAGetLastError()
  790. If $iRet = 10035 Then; WSAEWOULDBLOCK
  791. Return True; Asynchronous connect attempt has been started.
  792. EndIf
  793. SetExtended(1); Connected immediately
  794. Return True
  795. EndFunc ;==>_ASockConnect
  797. ; A wrapper function to ease all the pain in creating and filling the sockaddr struct
  798. Func ___SockAddr($sIP, $iPort, $iAddressFamily = 2)
  799. Local $iRet
  800. Local $stAddress
  802. If $hWs2_32 = -1 Then $hWs2_32 = DllOpen( "Ws2_32.dll" )
  804. $stAddress = DllStructCreate("short; ushort; uint; char[8]")
  805. If @error Then
  806. SetError(1, @error)
  807. Return False
  808. EndIf
  810. DllStructSetData($stAddress, 1, $iAddressFamily)
  811. $iRet = DllCall($hWs2_32, "ushort", "htons", "ushort", $iPort)
  812. DllStructSetData($stAddress, 2, $iRet[ 0 ])
  813. $iRet = DllCall($hWs2_32, "uint", "inet_addr", "str", $sIP)
  814. If $iRet[ 0 ] = 0xffffffff Then; INADDR_NONE
  815. $stAddress = 0; Deallocate
  816. SetError(2, ___WSAGetLastError())
  817. Return False
  818. EndIf
  819. DllStructSetData($stAddress, 3, $iRet[ 0 ])
  821. Return $stAddress
  822. EndFunc ;==>__SockAddr
  824. Func ___WSAGetLastError()
  825. If $hWs2_32 = -1 Then $hWs2_32 = DllOpen( "Ws2_32.dll" )
  826. Local $iRet = DllCall($hWs2_32, "int", "WSAGetLastError")
  827. If @error Then
  828. ;ConsoleWrite("+> _WSAGetLastError(): WSAGetLastError() failed. Script line number: " & @ScriptLineNumber & @CRLF)
  829. SetExtended(1)
  830. Return 0
  831. EndIf
  832. Return $iRet[ 0 ]
  833. EndFunc ;==>_WSAGetLastError
  836. ; Got these here:
  837. ; http://www.autoitscript.com/forum/index.php?showtopic=5620&hl=MAKELONG
  838. Func ___MakeLong($LoWord, $HiWord)
  839. Return BitOR($HiWord * 0x10000, BitAND($LoWord, 0xFFFF)); Thanks Larry
  840. EndFunc ;==>_MakeLong
  842. Func ___HiWord($Long)
  843. Return BitShift($Long, 16); Thanks Valik
  844. EndFunc ;==>_HiWord
  846. Func ___LoWord($Long)
  847. Return BitAND($Long, 0xFFFF); Thanks Valik
  848. EndFunc ;==>_LoWord
  851. ; ========================================= Array functions
  853. ; #FUNCTION# ====================================================================================================================
  854. ; Name...........: _ArrayDelete
  855. ; Description ...: Deletes the specified element from the given array.
  856. ; Syntax.........: _ArrayDelete(ByRef $avArray, $iElement)
  857. ; Parameters ....: $avArray - Array to modify
  858. ; $iElement - Element to delete
  859. ; Return values .: Success - New size of the array
  860. ; Failure - 0, sets @error to:
  861. ; |1 - $avArray is not an array
  862. ; |3 - $avArray has too many dimensions (only up to 2D supported)
  863. ; |(2 - Deprecated error code)
  864. ; Author ........: Cephas <cephas at clergy dot net>
  865. ; Modified.......: Jos van der Zande <jdeb at autoitscript dot com> - array passed ByRef, Ultima - 2D arrays supported, reworked function (no longer needs temporary array; faster when deleting from end)
  866. ; Remarks .......: If the array has one element left (or one row for 2D arrays), it will be set to "" after _ArrayDelete() is used on it.
  867. ; Related .......: _ArrayAdd, _ArrayInsert, _ArrayPop, _ArrayPush
  868. ; Link ..........;
  869. ; Example .......; Yes
  870. ; ===============================================================================================================================
  871. Func ___ArrayDelete(ByRef $avArray, $iElement)
  872. If Not IsArray($avArray) Then Return SetError(1, 0, 0)
  874. Local $iUBound = UBound($avArray, 1) - 1
  876. If Not $iUBound Then
  877. $avArray = ""
  878. Return 0
  879. EndIf
  881. ; Bounds checking
  882. If $iElement < 0 Then $iElement = 0
  883. If $iElement > $iUBound Then $iElement = $iUBound
  885. ; Move items after $iElement up by 1
  886. Switch UBound($avArray, 0)
  887. Case 1
  888. For $i = $iElement To $iUBound - 1
  889. $avArray[$i] = $avArray[$i + 1]
  890. Next
  891. ReDim $avArray[$iUBound]
  892. Case 2
  893. Local $iSubMax = UBound($avArray, 2) - 1
  894. For $i = $iElement To $iUBound - 1
  895. For $j = 0 To $iSubMax
  896. $avArray[$i][$j] = $avArray[$i + 1][$j]
  897. Next
  898. Next
  899. ReDim $avArray[$iUBound][$iSubMax + 1]
  900. Case Else
  901. Return SetError(3, 0, 0)
  902. EndSwitch
  904. Return $iUBound
  905. EndFunc ;==>_ArrayDelete
comments powered by Disqus