Pastebin UDF

SUBMITTED BY: Guest

DATE: May 28, 2013, 8:27 a.m.

FORMAT: Text only

SIZE: 12.8 kB

Raw Download

HITS: 1917

Report
  1. #Include-Once
  3. #include <WinHttp.au3>
  5. ; #INDEX# =========================================================================================
  6. ; Title .........: Pastebin UDF
  7. ; AutoIt Version : 3.3.8++
  8. ; Language ..... : English
  9. ; Description ...: Functions for use with Pastebin.com API
  10. ; Author(s) .....: mrflibblehat (danielcarroll@gmail.com)
  11. ; =================================================================================================
  13. ; #GLOBALS# =====================================================================================
  14. Global Const $vPasteBin = "pastebin.com" ;~ PasteBin Website
  15. Global Const $vAPIDevKey = "" ;~ Obtain The Developer Key From Pastebin
  16. Global $vOpen = 0, $vConnect = 0
  17. ; ===============================================================================================
  19. ; #CURRENT# =======================================================================================
  20. ;_PB_Open
  21. ;_PB_Close
  22. ;_CreatePaste
  23. ;_DeletePaste
  24. ;_CreateAPIUserKey
  25. ;_ListUserPastes
  26. ;_ListTrendingPastes
  27. ;_UserDetails
  28. ;_GetRawPaste
  29. ; =================================================================================================
  31. ; #FUNCTION# ====================================================================================================================
  32. ; Name...........: _PB_Open
  33. ; Description ...: Create Session and Connection Handle
  34. ; Syntax.........: _PB_Open
  35. ; Return values .: Failure - Returns 0 and Sets @Error:
  36. ; |@error = 1 - Error Opening WinHTTP Handle
  37. ; |@error = 2 - Error Opening WinHTTPConnect Handle
  38. ; Author ........: mrflibblehat (danielcarroll@gmail.com)
  39. ; ===============================================================================================================================
  40. Func _PB_Open()
  41. $vOpen = _WinHttpOpen()
  42. if (@error) then Return SetError(1, 0, "Error Opening WinHTTP Handle")
  43. $vConnect = _WinHttpConnect($vOpen, $vPasteBin)
  44. if (@error) then Return SetError(2, 0, "Error Opening WinHTTPConnect Handle")
  45. EndFunc
  47. ; #FUNCTION# ====================================================================================================================
  48. ; Name...........: _PB_Close
  49. ; Description ...: Close Session and Connection Handle
  50. ; Syntax.........: _PB_Close
  51. ; Author ........: mrflibblehat (danielcarroll@gmail.com)
  52. ; ===============================================================================================================================
  53. Func _PB_Close()
  54. _WinHttpCloseHandle($vConnect)
  55. _WinHttpCloseHandle($vOpen)
  56. EndFunc
  58. ; #FUNCTION# ====================================================================================================================
  59. ; Name...........: _CreatePaste
  60. ; Description ...: Creates a new paste and returns pastebin link
  61. ; Syntax.........: _CreatePaste($vPasteCode, $vPasteName[, $vPasteFormat = "text"[, $vPublicity = 1[, $vPasteExpireDate = "N" [, $vAPIUserKey = ""]]]] )
  62. ; Parameters ....: $vPasteCode - Put Paste Code Here
  63. ; $vPasteName - Name of Your Paste
  64. ; $vPasteFormat - Set Syntax Highlighting Format (autoit, php, c, c++, vb, html etc)
  65. ; $vPublicity - Set The Publicity of Your Paste (0 = Public, 1 = Private, 2 = Unlisted)
  66. ; $vPasteExpireDate - Set The Paste Expiry Date (N = Never, 10M = 10 Minutes, 1D = 1 Day, 1W = 1 Week etc)
  67. ; $vAPIUserKey - To Paste as a User, Only if You Have Created an API User Key (See _CreateAPIUserKey)
  68. ; Return values .: Success - Returns Pastebin Paste Link
  69. ; Author ........: mrflibblehat (danielcarroll@gmail.com)
  70. ; ===============================================================================================================================
  71. Func _CreatePaste($vPasteCode, $vPasteName, $vPasteFormat = "text", $vPublicity = 1, $vPasteExpireDate = "N", $vAPIUserKey = "")
  72. Local $sData = ("api_option=paste&api_user_key=" & $vAPIUserKey & "&api_paste_private=" & $vPublicity & "&api_paste_name=" & $vPasteName & "&api_paste_expire_date= " & $vPasteExpireDate & "&api_paste_format=" & $vPasteFormat & "&api_dev_key=" & $vAPIDevKey & "&api_paste_code=" & $vPasteCode)
  73. Local $vRequest = _WinHttpSimpleRequest($vConnect, "POST", "/api/api_post.php", $WINHTTP_NO_REFERER, $sData, "Content-Type: application/x-www-form-urlencoded")
  74. if (@error) then Return SetError(3, 0, "Unable To Send Request")
  75. Return SetError(0, 0, $vRequest)
  76. EndFunc
  78. ; #FUNCTION# ====================================================================================================================
  79. ; Name...........: _CreateAPIUserKey
  80. ; Description ...: Creates an API User Key
  81. ; Syntax.........: _CreateAPIUserKey($vUsername, $vPassword)
  82. ; Parameters ....: $vUsername - Pastebin Username
  83. ; $vPassword - Pastebin Password
  84. ; Return values .: Success - Returns Pastebin API User Key
  85. ; Author ........: mrflibblehat (danielcarroll@gmail.com)
  86. ; ===============================================================================================================================
  87. Func _CreateAPIUserKey($vUsername, $vPassword)
  88. Local $sData = ("api_dev_key=" & $vAPIDevKey & "&api_user_name=" & $vUsername & "&api_user_password=" & $vPassword)
  89. Local $vRequest = _WinHttpSimpleRequest($vConnect, "POST", "/api/api_post.php", $WINHTTP_NO_REFERER, $sData, "Content-Type: application/x-www-form-urlencoded")
  90. if (@error) then Return SetError(3, 0, "Unable To Send Request")
  91. Return SetError(0, 0, $vRequest)
  92. EndFunc
  94. ; #FUNCTION# ====================================================================================================================
  95. ; Name...........: _ListUserPastes
  96. ; Description ...: List Pastes by Given API User Key
  97. ; Syntax.........: _CreateAPIUserKey($vAPIUserKey[, $vAPIResultsLimit = 50])
  98. ; Parameters ....: $vAPIUserKey - Pastebin API User Key
  99. ; $vAPIResultsLimit - Limit Results Displayed
  100. ; Return values .: Success - Returns List of Pastebin Pastes
  101. ; Author ........: mrflibblehat (danielcarroll@gmail.com)
  102. ; ===============================================================================================================================
  103. Func _ListUserPastes($vAPIUserKey, $vAPIResultsLimit = 50)
  104. Local $sData = ("api_option=list&api_user_key=" & $vAPIUserKey &"&api_dev_key=" & $vAPIDevKey & "&api_results_limit=" & $vAPIResultsLimit)
  105. Local $vRequest = _WinHttpSimpleRequest($vConnect, "POST", "/api/api_post.php", $WINHTTP_NO_REFERER, $sData, "Content-Type: application/x-www-form-urlencoded")
  106. if (@error) then Return SetError(3, 0, "Unable To Send Request")
  107. Return SetError(0, 0, $vRequest)
  108. EndFunc
  110. ; #FUNCTION# ====================================================================================================================
  111. ; Name...........: _ListTrendingPastes
  112. ; Description ...: Creates an API User Key
  113. ; Syntax.........: _ListTrendingPastes()
  114. ; Parameters ....:
  115. ; Return values .: Success - Returns a 0 based array showing top trends
  116. ; Author ........: mrflibblehat (danielcarroll@gmail.com)
  117. ; ===============================================================================================================================
  118. Func _ListTrendingPastes()
  119. Local $vDataArr[18][10]
  120. Local $sData = ("api_option=trends&api_dev_key=" & $vAPIDevKey)
  121. Local $vRequest = _WinHttpSimpleRequest($vConnect, "POST", "/api/api_post.php", $WINHTTP_NO_REFERER, $sData, "Content-Type: application/x-www-form-urlencoded")
  122. if (@error) then Return SetError(3, 0, "Unable To Send Request")
  124. $vPasteKey = StringRegExp($vRequest, "<paste_key>(.*?)</paste_key>", 3)
  125. $vPasteDate = StringRegExp($vRequest, "<paste_date>(.*?)</paste_date>", 3)
  126. $vPasteTitle = StringRegExp($vRequest, "<paste_title>(.*?)</paste_title>", 3)
  127. $vPasteSize = StringRegExp($vRequest, "<paste_size>(.*?)</paste_size>", 3)
  128. $vPasteExpiry = StringRegExp($vRequest, "<paste_expire_date>(.*?)</paste_expire_date>", 3)
  129. $vPastePrivate = StringRegExp($vRequest, "<paste_private>(.*?)</paste_private>", 3)
  130. $vPasteFormatL = StringRegExp($vRequest, "<paste_format_long>(.*?)</paste_format_long>", 3)
  131. $vPasteFormatS = StringRegExp($vRequest, "<paste_format_short>(.*?)</paste_format_short>", 3)
  132. $vPasteURL = StringRegExp($vRequest, "<paste_url>(.*?)</paste_url>", 3)
  133. $vPasteHits = StringRegExp($vRequest, "<paste_hits>(.*?)</paste_hits>", 3)
  135. For $i = 0 to 17
  137. $vDataArr[$i][0] = $vPasteKey[$i] ;~ Paste Key
  138. $vDataArr[$i][1] = $vPasteDate[$i] ;~ Paste Date
  139. $vDataArr[$i][2] = $vPasteTitle[$i] ;~ Paste Title
  140. $vDataArr[$i][3] = $vPasteSize[$i] ;~ Paste Size (KB)
  141. $vDataArr[$i][4] = $vPasteExpiry[$i] ;~ Paste Expiry Time
  142. $vDataArr[$i][5] = $vPastePrivate[$i] ;~ Paste Publicity
  143. $vDataArr[$i][6] = $vPasteFormatL[$i] ;~ Paste Format Long
  144. $vDataArr[$i][7] = $vPasteFormatS[$i] ;~ Paste Formate Short
  145. $vDataArr[$i][8] = $vPasteURL[$i] ;~ Paste URL
  146. $vDataArr[$i][9] = $vPasteHits[$i] ;~ Paste Hits
  148. Next
  150. Return SetError(0, 0, $vDataArr)
  151. EndFunc
  153. ; #FUNCTION# ====================================================================================================================
  154. ; Name...........: _DeletePaste
  155. ; Description ...: Delete a Given Users Paste
  156. ; Syntax.........: _DeletePaste($vAPIUserKey, $vPasteKey)
  157. ; Parameters ....: $vAPIUserKey - Pastebin API User Key
  158. ; $vPasteKey - Paste Key, Obtained From _ListUserPastes Function
  159. ; Return values .: Success - Deletes Paste Returns "Paste Removed"
  160. ; Author ........: mrflibblehat (danielcarroll@gmail.com)
  161. ; ===============================================================================================================================
  162. Func _DeletePaste($vAPIUserKey, $vPasteKey)
  163. Local $sData = ("api_option=delete&api_user_key=" & $vAPIUserKey & "&api_dev_key=" & $vAPIDevKey & "&api_paste_key=" & $vPasteKey)
  164. Local $vRequest = _WinHttpSimpleRequest($vConnect, "POST", "/api/api_post.php", $WINHTTP_NO_REFERER, $sData, "Content-Type: application/x-www-form-urlencoded")
  165. if (@error) then Return SetError(3, 0, "Unable To Send Request")
  166. Return SetError(0, 0, $vRequest)
  167. EndFunc
  169. ; #FUNCTION# ====================================================================================================================
  170. ; Name...........: _UserDetails
  171. ; Description ...: Delete a Given Users Paste
  172. ; Syntax.........: _UserDetails($vAPIUserKey)
  173. ; Parameters ....: $vAPIUserKey - Pastebin API User Key
  174. ; Return values .: Success - Returns User Details
  175. ; Author ........: mrflibblehat (danielcarroll@gmail.com)
  176. ; ===============================================================================================================================
  177. Func _UserDetails($vAPIUserKey)
  178. Local $sData = ("api_option=userdetails&api_user_key=" & $vAPIUserKey & "&api_dev_key=" & $vAPIDevKey)
  179. Local $vRequest = _WinHttpSimpleRequest($vConnect, "POST", "/api/api_post.php", $WINHTTP_NO_REFERER, $sData, "Content-Type: application/x-www-form-urlencoded")
  180. if (@error) then Return SetError(3, 0, "Unable To Send Request")
  181. Return SetError(0, 0, $vRequest)
  182. EndFunc
  184. ; #FUNCTION# ====================================================================================================================
  185. ; Name...........: _GetRawPaste
  186. ; Description ...: Delete a Given Users Paste
  187. ; Syntax.........: _GetRawPaste($vPasteUrl)
  188. ; Parameters ....: $vPasteUrl - Pastebin URL
  189. ; Return values .: Success - Returns Paste
  190. ; Author ........: mrflibblehat (danielcarroll@gmail.com)
  191. ; ===============================================================================================================================
  192. Func _GetRawPaste($vPasteUrl)
  193. $vPasteKey = StringRegExp($vPasteUrl, "pastebin.com/(\H+)", 3)
  194. if (@error) then Return SetError(3, 0, "Unable To Read URL")
  195. Local $vRequest = _WinHttpSimpleRequest($vConnect, "GET", "/raw.php?i=" & $vPasteKey[0])
  196. if (@error) then Return SetError(3, 0, "Unable To Connect To URL")
  197. Return SetError(0, 0, $vRequest)
  198. EndFunc
comments powered by Disqus